Prepare for deploying to Maven

- Remove org.testcontainers BOM and declare version of org.testcontainers:jdbc explicitly, as previous solution resulted in versionless org.testcontainers:jdbc dependency in POM
- Change declaration from implementation to api for org.testcontainers:jdbc dependency so correct scope is applied in POM

Author: mrotteveel

build.gradle

@@ -1,5 +1,8 @@
 plugins {
     id 'java-library'
+    id 'nu.studer.credentials' version '1.0.7'
+    id 'maven'
+    id 'signing'
 }
 
 group 'org.firebirdsql'
@@ -12,15 +15,18 @@ ext {
     testContainersVersion = '1.11.3'
     lombokVersion = '1.18.8'
     jaybirdVersion = '3.0.6'
+
+    isReleaseVersion = !version.endsWith("SNAPSHOT")
+    set("signing.password", credentials."signing.password")
+    ossrhPassword = credentials.ossrhPassword
 }
 
 repositories {
     mavenCentral()
 }
 
 dependencies {
-    implementation platform("org.testcontainers:testcontainers-bom:$testContainersVersion")
-    implementation 'org.testcontainers:jdbc'
+    api "org.testcontainers:jdbc:$testContainersVersion"
 
     annotationProcessor "org.projectlombok:lombok:$lombokVersion"
     compileOnly "org.projectlombok:lombok:$lombokVersion"
@@ -32,3 +38,76 @@ dependencies {
     testImplementation 'commons-dbutils:commons-dbutils:1.6'
     testImplementation 'com.zaxxer:HikariCP:3.3.1'
 }
+
+jar {
+    manifest {
+        attributes(
+                'Implementation-Title': project.name,
+                'Implementation-Version': project.version,
+                'Automatic-Module-Name': 'org.firebirdsql.testcontainers'
+        )
+    }
+}
+
+task javadocJar(type: Jar) {
+    archiveClassifier = 'javadoc'
+    from javadoc
+}
+
+task sourcesJar(type: Jar) {
+    archiveClassifier = 'sources'
+    from sourceSets.main.allSource
+}
+
+artifacts {
+    archives javadocJar, sourcesJar
+}
+
+signing {
+    required { isReleaseVersion && gradle.taskGraph.hasTask("uploadArchives") }
+    sign configurations.archives
+}
+
+uploadArchives {
+    repositories {
+        mavenDeployer {
+            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
+
+            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
+                authentication(userName: ossrhUsername, password: ossrhPassword)
+            }
+
+            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
+                authentication(userName: ossrhUsername, password: ossrhPassword)
+            }
+
+            pom.project {
+                name 'firebird-testcontainers-java'
+                packaging 'jar'
+                description 'A module for Testcontainers.org to provide lightweight, throwaway instances of Firebird for JUnit tests.'
+                url 'https://github.com/FirebirdSQL/firebird-testcontainers-java'
+
+                scm {
+                    connection 'scm:git:https://github.com/FirebirdSQL/firebird-testcontainers-java.git'
+                    developerConnection 'scm:git:git@github.com:FirebirdSQL/firebird-testcontainers-java.git'
+                    url 'https://github.com/FirebirdSQL/firebird-testcontainers-java'
+                }
+
+                licenses {
+                    license {
+                        name 'The MIT License'
+                        url 'https://opensource.org/licenses/MIT'
+                    }
+                }
+
+                developers {
+                    developer {
+                        id 'mrotteveel'
+                        name 'Mark Rotteveel'
+                        email 'mark@lawinegevaar.nl'
+                    }
+                }
+            }
+        }
+    }
+}

devdoc/deploy.md

@@ -0,0 +1,32 @@
+Deploying
+=========
+
+To deploy to Maven use
+
+```
+gradlew clean uploadArchives -PcredentialsPassphrase=<credentials password>
+```
+
+Where `<credentials password>` is the password used to add the credentials (see 
+also below).
+
+To be able to deploy, you need the following:
+
+a `<homedir>/.gradle/gradle.properties` with the following properties:
+
+```
+signing.keyId=<gpg key id>
+signing.secretKeyRingFile=<path to your secring.gpg> 
+
+ossrhUsername=<sonatype OSSRH username>
+```
+
+In addition, you need to set the following credentials
+
+```
+./gradlew addCredentials --key signing.password --value <your secret key password> -PcredentialsPassphrase=<credentials password> 
+./gradlew addCredentials --key ossrhPassword --value <your sonatyp OSSRH password> -PcredentialsPassphrase=<credentials password> 
+```
+
+See https://github.com/etiennestuder/gradle-credentials-plugin for details on
+credentials.

gradle.properties

@@ -0,0 +1,2 @@
+# Default value so the build script doesn't break
+ossrhUsername=don't break the build