From d5561a9d5062c029f7f998ad9d5d5239e3693213 Mon Sep 17 00:00:00 2001
From: Luciano Gomes <luciano.dittgen@ossystems.com.br>
Date: Fri, 22 May 2026 16:16:13 -0300
Subject: [PATCH 1/5] recipes-core/easysplash: Update for modern OE-Core and
 fix service installation

easysplash-common-2.0.inc: Drop the redundant 'S' assignment, as it defaults to /git for git-based recipes.

easysplash-config_2.0.0.bb: Use  for the configuration file source to comply with the recent OE-Core 'unpack-to-unpackdir' changes.

easysplash_2.0.0.bb: Explicitly pass 'INIT' and 'SYSTEMD' flags to 'oe_runmake' during the service installation in 'do_install:append'. This ensures the build system correctly identifies which service files to install based on the enabled PACKAGECONFIG, while removing these flags from the default PACKAGECONFIG variables where they were not effectively reaching the install target.
---
 recipes-core/easysplash/easysplash-common-2.0.inc  |  1 -
 recipes-core/easysplash/easysplash-config_2.0.0.bb |  2 +-
 recipes-core/easysplash/easysplash_2.0.0.bb        | 10 ++++++----
 3 files changed, 7 insertions(+), 6 deletions(-)

diff --git a/recipes-core/easysplash/easysplash-common-2.0.inc b/recipes-core/easysplash/easysplash-common-2.0.inc
index 913cf31..3fad888 100644
--- a/recipes-core/easysplash/easysplash-common-2.0.inc
+++ b/recipes-core/easysplash/easysplash-common-2.0.inc
@@ -9,7 +9,6 @@ SRC_URI = "git://github.com/OSSystems/EasySplash.git;branch=${SRCBRANCH};protoco
 
 PV = "2.0.0"
 
-S = "${WORKDIR}/git"
 
 EXTRA_OEMAKE += " \
     prefix=${prefix} \
diff --git a/recipes-core/easysplash/easysplash-config_2.0.0.bb b/recipes-core/easysplash/easysplash-config_2.0.0.bb
index 8673f5e..15e6093 100644
--- a/recipes-core/easysplash/easysplash-config_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash-config_2.0.0.bb
@@ -4,7 +4,7 @@ LICENSE = "CLOSED"
 SRC_URI += "file://easysplash.default"
 
 do_install() {
-    install -Dm 0644 ${WORKDIR}/easysplash.default ${D}${sysconfdir}/default/easysplash
+    install -Dm 0644 ${UNPACKDIR}/easysplash.default ${D}${sysconfdir}/default/easysplash
 }
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/recipes-core/easysplash/easysplash_2.0.0.bb b/recipes-core/easysplash/easysplash_2.0.0.bb
index 8b4ac48..8a623c0 100644
--- a/recipes-core/easysplash/easysplash_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash_2.0.0.bb
@@ -35,12 +35,14 @@ PACKAGECONFIG ?= "\
     ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
 "
 
-PACKAGECONFIG[sysvinit] = "INIT=1, INIT=0,"
-PACKAGECONFIG[systemd] = "SYSTEMD=1, SYSTEM=0, systemd"
+PACKAGECONFIG[sysvinit] = ",,"
+PACKAGECONFIG[systemd] = ",, systemd"
 
 do_install:append() {
-    (cd ${S} ; oe_runmake install-service DESTDIR=${D})
-    rm ${D}${sysconfdir}/default/easysplash
+    (cd ${S} ; oe_runmake install-service DESTDIR=${D} \
+          ${@bb.utils.contains('PACKAGECONFIG', 'sysvinit', 'INIT=1', 'INIT=0', d)} \
+          ${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'SYSTEMD=1', 'SYSTEMD=0', d)})
+      rm ${D}${sysconfdir}/default/easysplash
 }
 
 RDEPENDS:${PN} += "easysplash-config"

From bf86df1c8977a72ee026ab92952a5144f9181aab Mon Sep 17 00:00:00 2001
From: Luciano Gomes <luciano.dittgen@ossystems.com.br>
Date: Thu, 28 May 2026 09:54:01 -0300
Subject: [PATCH 2/5] recipes-staging/gstremamer: Enable KMS support in
 plugins-bad

Enable the kms PACKAGECONFIG so the gstreamer1.0-plugins-bad-kms package is
  built from the layer metadata. EasySplash animation recipes depend on this
  runtime package, so keeping the setting in the layer avoids requiring a
  local.conf workaround and fixes the build-deps QA issue.
---
 recipes-staging/gstreamer/gstreamer1.0-plugins-bad_%.bbappend | 1 +
 1 file changed, 1 insertion(+)
 create mode 100644 recipes-staging/gstreamer/gstreamer1.0-plugins-bad_%.bbappend

diff --git a/recipes-staging/gstreamer/gstreamer1.0-plugins-bad_%.bbappend b/recipes-staging/gstreamer/gstreamer1.0-plugins-bad_%.bbappend
new file mode 100644
index 0000000..f03aa32
--- /dev/null
+++ b/recipes-staging/gstreamer/gstreamer1.0-plugins-bad_%.bbappend
@@ -0,0 +1 @@
+PACKAGECONFIG:append = " kms"

From 4e922acc46e0ffefc18cb86e0f0dda88cca19ac8 Mon Sep 17 00:00:00 2001
From: Luciano Gomes <luciano.dittgen@ossystems.com.br>
Date: Thu, 28 May 2026 11:55:34 -0300
Subject: [PATCH 3/5] recipes-core/easysplash: Clean up recipe metadata

Update the EasySplash recipes to satisfy oelint checks by adding missing
  metadata, fixing SPDX license syntax, avoiding duplicate license assignments,
  and using the expected BitBake append spacing.

  Rename the EasySplash animation class to use an underscore and update the
  animation recipes to inherit the new class name.
---
 ...n.bbclass => easysplash_animation.bbclass} |  0
 .../easysplash-animation-default_2.0.0.bb     | 19 ++++++++-----
 .../easysplash-animation-ossystems_2.0.0.bb   | 19 ++++++++-----
 .../easysplash/easysplash-common-2.0.inc      | 13 ++-------
 recipes-core/easysplash/easysplash-crates.inc |  2 +-
 recipes-core/easysplash/easysplash_2.0.0.bb   | 28 +++++++++++--------
 6 files changed, 45 insertions(+), 36 deletions(-)
 rename classes/{easysplash-animation.bbclass => easysplash_animation.bbclass} (100%)

diff --git a/classes/easysplash-animation.bbclass b/classes/easysplash_animation.bbclass
similarity index 100%
rename from classes/easysplash-animation.bbclass
rename to classes/easysplash_animation.bbclass
diff --git a/recipes-core/easysplash/easysplash-animation-default_2.0.0.bb b/recipes-core/easysplash/easysplash-animation-default_2.0.0.bb
index 3662505..065798c 100644
--- a/recipes-core/easysplash/easysplash-animation-default_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash-animation-default_2.0.0.bb
@@ -1,9 +1,14 @@
 SUMMARY = "Default EasySplash Animation intended for general use"
+DESCRIPTION = "Default EasySplash animation assets intended for general use."
+HOMEPAGE = "https://github.com/OSSystems/EasySplash"
+BUGTRACKER = "https://github.com/OSSystems/EasySplash/issues"
+SECTION = "graphics"
+CVE_PRODUCT = "easysplash"
 LICENSE = "CLOSED"
 
 require easysplash-common-2.0.inc
 
-inherit easysplash-animation
+inherit easysplash_animation
 
 do_configure[noexec] = "1"
 do_compile[noexec] = "1"
@@ -21,15 +26,15 @@ do_install() {
 
 ALTERNATIVE_PRIORITY[animation] = "10"
 
-RDEPENDS:${PN} += " \
+RDEPENDS:${PN} += "\
     gstreamer1.0-libav \
-    gstreamer1.0-plugins-base-playback \
-    gstreamer1.0-plugins-good-isomp4 \
-    gstreamer1.0-plugins-bad-kms \
     gstreamer1.0-plugins-bad-camerabin \
-    gstreamer1.0-plugins-good-videofilter \
+    gstreamer1.0-plugins-bad-kms \
+    gstreamer1.0-plugins-base-playback \
+    gstreamer1.0-plugins-base-typefindfunctions \
     gstreamer1.0-plugins-base-videoconvertscale \
     gstreamer1.0-plugins-good-deinterlace \
+    gstreamer1.0-plugins-good-isomp4 \
     gstreamer1.0-plugins-good-multifile \
-    gstreamer1.0-plugins-base-typefindfunctions \
+    gstreamer1.0-plugins-good-videofilter \
 "
diff --git a/recipes-core/easysplash/easysplash-animation-ossystems_2.0.0.bb b/recipes-core/easysplash/easysplash-animation-ossystems_2.0.0.bb
index 6634176..fa6c2d6 100644
--- a/recipes-core/easysplash/easysplash-animation-ossystems_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash-animation-ossystems_2.0.0.bb
@@ -1,9 +1,14 @@
 SUMMARY = "O.S. Systems EasySplash Animation"
+DESCRIPTION = "O.S. Systems branded EasySplash animation assets."
+HOMEPAGE = "https://github.com/OSSystems/EasySplash"
+BUGTRACKER = "https://github.com/OSSystems/EasySplash/issues"
+SECTION = "graphics"
+CVE_PRODUCT = "easysplash"
 LICENSE = "CLOSED"
 
 require easysplash-common-2.0.inc
 
-inherit easysplash-animation
+inherit easysplash_animation
 
 do_configure[noexec] = "1"
 do_compile[noexec] = "1"
@@ -19,15 +24,15 @@ do_install() {
     mv ${D}${base_libdir}/easysplash/ossystems-demo ${D}${base_libdir}/easysplash/${PN}
 }
 
-RDEPENDS:${PN} += " \
+RDEPENDS:${PN} += "\
     gstreamer1.0-libav \
-    gstreamer1.0-plugins-base-playback \
-    gstreamer1.0-plugins-good-isomp4 \
-    gstreamer1.0-plugins-bad-kms \
     gstreamer1.0-plugins-bad-camerabin \
-    gstreamer1.0-plugins-good-videofilter \
+    gstreamer1.0-plugins-bad-kms \
+    gstreamer1.0-plugins-base-playback \
+    gstreamer1.0-plugins-base-typefindfunctions \
     gstreamer1.0-plugins-base-videoconvertscale \
     gstreamer1.0-plugins-good-deinterlace \
+    gstreamer1.0-plugins-good-isomp4 \
     gstreamer1.0-plugins-good-multifile \
-    gstreamer1.0-plugins-base-typefindfunctions \
+    gstreamer1.0-plugins-good-videofilter \
 "
diff --git a/recipes-core/easysplash/easysplash-common-2.0.inc b/recipes-core/easysplash/easysplash-common-2.0.inc
index 3fad888..39bb6f8 100644
--- a/recipes-core/easysplash/easysplash-common-2.0.inc
+++ b/recipes-core/easysplash/easysplash-common-2.0.inc
@@ -1,16 +1,9 @@
-LICENSE = "Apache-2.0|MIT"
-LIC_FILES_CHKSUM = "file://LICENSE-APACHE-2.0;md5=1836efb2eb779966696f473ee8540542"
-LIC_FILES_CHKSUM = "file://LICENSE-MIT;md5=b377b220f43d747efdec40d69fcaa69d"
-
-SRCREV = "81a44392efe15fd12ea673f1c828a52e95103eea"
-SRCBRANCH = "master"
-
-SRC_URI = "git://github.com/OSSystems/EasySplash.git;branch=${SRCBRANCH};protocol=https"
-
 PV = "2.0.0"
 
+SRC_URI = "git://github.com/OSSystems/EasySplash.git;branch=master;protocol=https"
+SRCREV = "81a44392efe15fd12ea673f1c828a52e95103eea"
 
-EXTRA_OEMAKE += " \
+EXTRA_OEMAKE += "\
     prefix=${prefix} \
     sysconfdir=${sysconfdir} \
     sbindir=${bindir} \
diff --git a/recipes-core/easysplash/easysplash-crates.inc b/recipes-core/easysplash/easysplash-crates.inc
index d614af3..830d49f 100644
--- a/recipes-core/easysplash/easysplash-crates.inc
+++ b/recipes-core/easysplash/easysplash-crates.inc
@@ -1,7 +1,7 @@
 # Autogenerated with 'bitbake -c update_crates easysplash'
 
 # from Cargo.lock
-SRC_URI += " \
+SRC_URI += "\
     crate://crates.io/anyhow/1.0.59 \
     crate://crates.io/argh/0.1.8 \
     crate://crates.io/argh_derive/0.1.8 \
diff --git a/recipes-core/easysplash/easysplash_2.0.0.bb b/recipes-core/easysplash/easysplash_2.0.0.bb
index 8a623c0..4d35c5f 100644
--- a/recipes-core/easysplash/easysplash_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash_2.0.0.bb
@@ -1,11 +1,23 @@
 # Auto-Generated by cargo-bitbake 0.3.16-alpha.0
 #
 
+SUMMARY = "Graphical boot animation application"
 DESCRIPTION = "EasySplash is an application that runs early the OS boot for showing graphical \
-animation while the boot process itself happens in the background. \
-The app is built on Rust and binds to GStreamer, so it can run in any backend that supports both."
+               animation while the boot process itself happens in the background. \
+               The app is built on Rust and binds to GStreamer, so it can run in any backend that supports both."
+HOMEPAGE = "https://github.com/OSSystems/EasySplash"
+BUGTRACKER = "https://github.com/OSSystems/EasySplash/issues"
+SECTION = "graphics"
+CVE_PRODUCT = "easysplash"
+LICENSE = "Apache-2.0 | MIT"
+LIC_FILES_CHKSUM = "\
+    file://LICENSE-APACHE-2.0;md5=1836efb2eb779966696f473ee8540542 \
+    file://LICENSE-MIT;md5=b377b220f43d747efdec40d69fcaa69d \
+"
+DEPENDS += "glib-2.0 gstreamer1.0"
 
-require easysplash-common-2.0.inc easysplash-crates.inc
+require easysplash-common-2.0.inc
+require easysplash-crates.inc
 
 inherit cargo pkgconfig systemd update-rc.d cargo-update-recipe-crates
 
@@ -13,20 +25,14 @@ inherit cargo pkgconfig systemd update-rc.d cargo-update-recipe-crates
 # DEFAULT_PREFERENCE = "-1"
 
 CARGO_SRC_DIR = ""
-PV:append = ".AUTOINC+724e1c7edc"
-
-LICENSE = "Apache-2.0|MIT"
-LIC_FILES_CHKSUM = "file://LICENSE-APACHE-2.0;md5=1836efb2eb779966696f473ee8540542"
-LIC_FILES_CHKSUM = "file://LICENSE-MIT;md5=b377b220f43d747efdec40d69fcaa69d"
-
-DEPENDS = "glib-2.0 gstreamer1.0"
+PV .= ".AUTOINC+724e1c7edc"
 
 INITSCRIPT_NAME = "${PN}-start"
 INITSCRIPT_PARAMS:${PN} = "start 5 S ."
 
 SYSTEMD_SERVICE:${PN} = "${PN}-start.service ${PN}-quit.service"
 
-EXTRA_CARGO_FLAGS += " \
+CARGO_BUILD_FLAGS += "\
     ${@bb.utils.contains('PACKAGECONFIG', 'systemd', '--features systemd', '', d)} \
 "
 

From 393cea244b5b05773240c5a84716fd82568bba46 Mon Sep 17 00:00:00 2001
From: Luciano Gomes <luciano.dittgen@ossystems.com.br>
Date: Thu, 28 May 2026 16:21:08 -0300
Subject: [PATCH 4/5] recipes-core: Scope core bbappend customizations to OEL

- Scope base-files locale handling to the oel override and generate locale.conf during do_install.
  - Scope BusyBox configuration fragments to the oel override.
  - Scope the systemd util-linux-umount runtime dependency to the oel override.
  - Keep the os-release build number append spacing consistent with BitBake
    append syntax.
---
 recipes-core/base-files/base-files_%.bbappend | 20 +++++--------------
 recipes-core/busybox/busybox_%.bbappend       |  4 ++--
 recipes-core/os-release/os-release.bbappend   |  2 +-
 recipes-core/systemd/systemd_%.bbappend       |  2 +-
 4 files changed, 9 insertions(+), 19 deletions(-)

diff --git a/recipes-core/base-files/base-files_%.bbappend b/recipes-core/base-files/base-files_%.bbappend
index 357c5db..b78fe20 100644
--- a/recipes-core/base-files/base-files_%.bbappend
+++ b/recipes-core/base-files/base-files_%.bbappend
@@ -1,22 +1,12 @@
-FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
+FILESEXTRAPATHS:prepend:oel := "${THISDIR}/${PN}:"
 
-SRC_URI += "file://profile.d_locale.sh"
+SRC_URI:append:oel = " file://profile.d_locale.sh"
 
-DEFAULT_SYSTEM_LOCALE ??= ""
-
-do_generate_locale_conf() {
-    if [ "${@d.getVar('DEFAULT_SYSTEM_LOCALE', True)}" != "" ]; then
-        cat > ${WORKDIR}/locale.conf <<EOF
-LANG=${DEFAULT_SYSTEM_LOCALE}
-EOF
-    fi
-}
-addtask do_generate_locale_conf after do_compile before do_install
-
-do_install:append() {
+do_install:append:oel() {
     install -Dm 0644 ${S}/profile.d_locale.sh ${D}${sysconfdir}/profile.d/locale.sh
 
     if [ "${@d.getVar('DEFAULT_SYSTEM_LOCALE', True)}" != "" ]; then
-        install -Dm 0644 ${WORKDIR}/locale.conf ${D}${sysconfdir}/locale.conf
+        install -d ${D}${sysconfdir}
+        printf 'LANG=%s\n' "${DEFAULT_SYSTEM_LOCALE}" > ${D}${sysconfdir}/locale.conf
     fi
 }
diff --git a/recipes-core/busybox/busybox_%.bbappend b/recipes-core/busybox/busybox_%.bbappend
index 9a066d6..5b0e6c8 100644
--- a/recipes-core/busybox/busybox_%.bbappend
+++ b/recipes-core/busybox/busybox_%.bbappend
@@ -1,5 +1,5 @@
-FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
-SRC_URI:append:oel = "\
+FILESEXTRAPATHS:prepend:oel := "${THISDIR}/files:"
+SRC_URI:append:oel = " \
     file://setsid.cfg \
     file://resize.cfg \
     file://pidof.cfg \
diff --git a/recipes-core/os-release/os-release.bbappend b/recipes-core/os-release/os-release.bbappend
index 3825a83..d6d3463 100644
--- a/recipes-core/os-release/os-release.bbappend
+++ b/recipes-core/os-release/os-release.bbappend
@@ -1,4 +1,4 @@
 OS_RELEASE_FIELDS:append:oel = " BUILD_NUMBER"
 
 # Append build number for development builds
-VERSION:append:oel = "${@' (build %s)' % BUILD_NUMBER if 'BUILD_NUMBER' in d and DISTRO_VERSION.endswith('+devel') else ''}"
+VERSION:append:oel = " ${@'(build %s)' % BUILD_NUMBER if 'BUILD_NUMBER' in d and DISTRO_VERSION.endswith('+devel') else ''}"
diff --git a/recipes-core/systemd/systemd_%.bbappend b/recipes-core/systemd/systemd_%.bbappend
index 15e476e..3d322a4 100644
--- a/recipes-core/systemd/systemd_%.bbappend
+++ b/recipes-core/systemd/systemd_%.bbappend
@@ -1 +1 @@
-RDEPENDS:${PN} += "util-linux-umount"
+RDEPENDS:${PN}:append:oel = " util-linux-umount"

From 6cf743aad97a5c9316012a75d5a784fa81b99a2e Mon Sep 17 00:00:00 2001
From: Luciano Gomes <luciano.dittgen@ossystems.com.br>
Date: Thu, 28 May 2026 18:00:02 -0300
Subject: [PATCH 5/5] recipes-core: Complete psplash, easysplash and
 tiny-init-system metadata

Update core recipes to align their metadata and packaging details:
  - Restrict psplash FILESEXTRAPATHS to the oel distro override.
  - Complete EasySplash recipe metadata and explicitly disable BBCLASSEXTEND
    where native/nativesdk variants are not useful.
  - Rename tiny-init-system to include its recipe version, add missing metadata,
    use a recipe-local MIT license file, and make FILES additive.
---
 .../easysplash-animation-default_2.0.0.bb     |  2 ++
 .../easysplash-animation-ossystems_2.0.0.bb   |  2 ++
 .../easysplash/easysplash-config_2.0.0.bb     |  7 +++++
 recipes-core/easysplash/easysplash-crates.inc |  1 +
 recipes-core/easysplash/easysplash_2.0.0.bb   |  2 ++
 .../initramfs-framework-psplash_1.0.bb        |  2 ++
 recipes-core/psplash/psplash_git.bbappend     |  2 +-
 .../tiny-init-system/files/COPYING.MIT        | 17 +++++++++++
 .../tiny-init-system/tiny-init-system.bb      | 19 ------------
 .../tiny-init-system/tiny-init-system_1.0.bb  | 29 +++++++++++++++++++
 10 files changed, 63 insertions(+), 20 deletions(-)
 create mode 100644 recipes-core/tiny-init-system/files/COPYING.MIT
 delete mode 100644 recipes-core/tiny-init-system/tiny-init-system.bb
 create mode 100644 recipes-core/tiny-init-system/tiny-init-system_1.0.bb

diff --git a/recipes-core/easysplash/easysplash-animation-default_2.0.0.bb b/recipes-core/easysplash/easysplash-animation-default_2.0.0.bb
index 065798c..58efdfa 100644
--- a/recipes-core/easysplash/easysplash-animation-default_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash-animation-default_2.0.0.bb
@@ -38,3 +38,5 @@ RDEPENDS:${PN} += "\
     gstreamer1.0-plugins-good-multifile \
     gstreamer1.0-plugins-good-videofilter \
 "
+
+BBCLASSEXTEND = ""
diff --git a/recipes-core/easysplash/easysplash-animation-ossystems_2.0.0.bb b/recipes-core/easysplash/easysplash-animation-ossystems_2.0.0.bb
index fa6c2d6..e410f4b 100644
--- a/recipes-core/easysplash/easysplash-animation-ossystems_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash-animation-ossystems_2.0.0.bb
@@ -36,3 +36,5 @@ RDEPENDS:${PN} += "\
     gstreamer1.0-plugins-good-multifile \
     gstreamer1.0-plugins-good-videofilter \
 "
+
+BBCLASSEXTEND = ""
diff --git a/recipes-core/easysplash/easysplash-config_2.0.0.bb b/recipes-core/easysplash/easysplash-config_2.0.0.bb
index 15e6093..5706cf5 100644
--- a/recipes-core/easysplash/easysplash-config_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash-config_2.0.0.bb
@@ -1,4 +1,9 @@
 SUMMARY = "Easysplash Configuration"
+DESCRIPTION = "Default EasySplash configuration installed under /etc/default."
+HOMEPAGE = "https://github.com/OSSystems/EasySplash"
+BUGTRACKER = "https://github.com/OSSystems/EasySplash/issues"
+SECTION = "graphics"
+CVE_PRODUCT = "easysplash"
 LICENSE = "CLOSED"
 
 SRC_URI += "file://easysplash.default"
@@ -8,3 +13,5 @@ do_install() {
 }
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+BBCLASSEXTEND = ""
diff --git a/recipes-core/easysplash/easysplash-crates.inc b/recipes-core/easysplash/easysplash-crates.inc
index 830d49f..6228666 100644
--- a/recipes-core/easysplash/easysplash-crates.inc
+++ b/recipes-core/easysplash/easysplash-crates.inc
@@ -1,6 +1,7 @@
 # Autogenerated with 'bitbake -c update_crates easysplash'
 
 # from Cargo.lock
+# nooelint: oelint.vars.srcuridomains
 SRC_URI += "\
     crate://crates.io/anyhow/1.0.59 \
     crate://crates.io/argh/0.1.8 \
diff --git a/recipes-core/easysplash/easysplash_2.0.0.bb b/recipes-core/easysplash/easysplash_2.0.0.bb
index 4d35c5f..86e5397 100644
--- a/recipes-core/easysplash/easysplash_2.0.0.bb
+++ b/recipes-core/easysplash/easysplash_2.0.0.bb
@@ -52,3 +52,5 @@ do_install:append() {
 }
 
 RDEPENDS:${PN} += "easysplash-config"
+
+BBCLASSEXTEND = ""
diff --git a/recipes-core/initrdscripts/initramfs-framework-psplash_1.0.bb b/recipes-core/initrdscripts/initramfs-framework-psplash_1.0.bb
index d5710ee..9344c28 100644
--- a/recipes-core/initrdscripts/initramfs-framework-psplash_1.0.bb
+++ b/recipes-core/initrdscripts/initramfs-framework-psplash_1.0.bb
@@ -13,6 +13,8 @@ SRC_URI = " \
     file://psplash-finish \
 "
 
+S = "${UNPACKDIR}"
+
 do_install() {
     # psplash
     install -Dm 0755 ${S}/psplash ${D}/init.d/11-psplash
diff --git a/recipes-core/psplash/psplash_git.bbappend b/recipes-core/psplash/psplash_git.bbappend
index 09fe6aa..4af5d4c 100644
--- a/recipes-core/psplash/psplash_git.bbappend
+++ b/recipes-core/psplash/psplash_git.bbappend
@@ -1,4 +1,4 @@
-FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+FILESEXTRAPATHS:prepend:oel := "${THISDIR}/files:"
 
 SRC_URI:append:oel = " \
     file://psplash-colors.h \
diff --git a/recipes-core/tiny-init-system/files/COPYING.MIT b/recipes-core/tiny-init-system/files/COPYING.MIT
new file mode 100644
index 0000000..dbcba26
--- /dev/null
+++ b/recipes-core/tiny-init-system/files/COPYING.MIT
@@ -0,0 +1,17 @@
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
+THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR
+OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
+ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
+OTHER DEALINGS IN THE SOFTWARE.
diff --git a/recipes-core/tiny-init-system/tiny-init-system.bb b/recipes-core/tiny-init-system/tiny-init-system.bb
deleted file mode 100644
index ffb01b0..0000000
--- a/recipes-core/tiny-init-system/tiny-init-system.bb
+++ /dev/null
@@ -1,19 +0,0 @@
-SUMMARY = "Basic init system for constrained systems"
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
-
-SRC_URI = "\
-    file://init \
-    file://rc.local.sample \
-"
-
-do_configure[noexec] = "1"
-do_compile[noexec] = "1"
-
-do_install() {
-    install -m 0755 ${S}/init ${D}
-    install -Dm 0755 ${S}/rc.local.sample ${D}${sysconfdir}/rc.local.sample
-}
-
-FILES:${PN} = "/init ${sysconfdir}/rc.local.sample"
-RDEPENDS:${PN} = "busybox"
diff --git a/recipes-core/tiny-init-system/tiny-init-system_1.0.bb b/recipes-core/tiny-init-system/tiny-init-system_1.0.bb
new file mode 100644
index 0000000..ea7ef63
--- /dev/null
+++ b/recipes-core/tiny-init-system/tiny-init-system_1.0.bb
@@ -0,0 +1,29 @@
+SUMMARY = "Basic init system for constrained systems"
+DESCRIPTION = "Tiny init system for constrained systems based on BusyBox."
+HOMEPAGE = "https://github.com/OSSystemsEmbeddedLinux/meta-ossystems-base"
+BUGTRACKER = "https://github.com/OSSystemsEmbeddedLinux/meta-ossystems-base/issues"
+SECTION = "base"
+CVE_PRODUCT = "tiny-init-system"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING.MIT;md5=40eb1f165a0cf177f2660b7d4223cc56"
+
+SRC_URI = "\
+    file://COPYING.MIT \
+    file://init \
+    file://rc.local.sample \
+"
+
+S = "${UNPACKDIR}"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+do_install() {
+    install -m 0755 ${S}/init ${D}
+    install -Dm 0755 ${S}/rc.local.sample ${D}${sysconfdir}/rc.local.sample
+}
+
+FILES:${PN} += "/init ${sysconfdir}/rc.local.sample"
+RDEPENDS:${PN} = "busybox"
+
+BBCLASSEXTEND = ""