Relocate JVM host dependent config loading code to new host ns

Author: JarrodCTaylor

client/deps.edn

@@ -1,4 +1,4 @@
-{:paths ["src"]
+{:paths ["src" "src-jvm"]
  :deps {org.clojure/clojure           {:mvn/version "1.12.5"}
         org.clojure/tools.reader      {:mvn/version "1.6.0"}
         org.clojure/tools.deps.config {:mvn/version "0.1.5"}

client/src-jvm/clojure_cli/repl/host.clj

@@ -0,0 +1,53 @@
+(ns clojure-cli.repl.host
+  (:require
+    [clojure.java.shell :as sh]
+    [clojure.string :as str]
+    [clojure.tools.deps.config :as dc]))
+
+(set! *warn-on-reflection* true)
+
+(defn cli-classpath
+  "CP for the config's deps.edn -Srepro excludes global ~/.clojure/deps.edn"
+  [location lib]
+  (when (.isFile (dc/data-file location lib "deps.edn"))
+    (let [dir (dc/data-dir location lib)
+          {:keys [exit out err]} (sh/sh "clojure" "-Srepro" "-A:clojure-cli.repl/client" "-Spath" :dir (str dir))]
+      (if (zero? exit)
+        (str/trim out)
+        (println "clojure-cli.repl: could not resolve deps.edn in" (str dir) "-" (str/trim err))))))
+
+(defn classpath-files [^java.io.File dir ^String cp]
+  (map #(.toFile (.resolve (.toPath dir) ^String %))
+       (.split cp java.io.File/pathSeparator)))
+
+(defn config-classpath [location lib]
+  (when-let [cp (cli-classpath location lib)]
+    (classpath-files (dc/data-dir location lib) cp)))
+
+(defn load-config
+  "Puts the config classpath on a DynamicClassLoader installed as the thread's
+   context loader. A new loader is required because the app loader cannot be
+   extended. Returns the config map."
+  [lib]
+  (let [entries (distinct (mapcat #(config-classpath % lib) [:project :user]))]
+    (when (seq entries)
+      (let [thread (Thread/currentThread)
+            loader (clojure.lang.DynamicClassLoader. (.getContextClassLoader thread))]
+        (doseq [^java.io.File f entries]
+          (.addURL loader (.toURL (.toURI f))))
+        (.setContextClassLoader thread loader))))
+  (dc/config lib))
+
+(defn resolve-prompt
+  "Resolves the configured :prompt var, or nil when none is configured."
+  [config]
+  (when-let [prompt (:prompt config)]
+    (or (requiring-resolve prompt)
+        (throw (ex-info (str "clojure-cli.repl: :prompt var not found: " prompt) {:prompt prompt})))))
+
+(defn apply-keybindings
+  [config reader]
+  (when-let [keybindings (:keybindings config)]
+    (if-let [f (requiring-resolve keybindings)]
+      (f reader)
+      (throw (ex-info (str "clojure-cli.repl: :keybindings var not found: " keybindings) {:keybindings keybindings})))))

client/src/clojure_cli/repl/client.clj

@@ -1,9 +1,9 @@
 (ns clojure-cli.repl.client
   (:require
     [clojure.edn :as edn]
-    [clojure.java.shell :as sh]
     [clojure.string :as str]
     [clojure.tools.deps.config :as dc]
+    [clojure-cli.repl.host :as host]
     [clojure-cli.repl.nrepl :as nrepl]
     [clojure-cli.repl.api :as api]
     [clojure-cli.repl.paredit :as paredit]
@@ -145,47 +145,9 @@
   [{:text @api/current-ns :style {:fg :blue :bold true}}
    {:text " => "}])
 
-(defn resolve-prompt [config]
-  (if-let [prompt (:prompt config)]
-    (or (requiring-resolve prompt)
-        (throw (ex-info (str "clojure-cli.repl: :prompt var not found: " prompt) {:prompt prompt})))
-    default-prompt))
-
 (defn render-prompt ^String [prompt-fn]
   (.toAnsi (color/build-attrib-str (prompt-fn))))
 
-(defn cli-classpath
-  "CP for the config's deps.edn -Srepro excludes global ~/.clojure/deps.edn"
-  [location lib]
-  (when (.isFile (dc/data-file location lib "deps.edn"))
-    (let [dir (dc/data-dir location lib)
-          {:keys [exit out err]} (sh/sh "clojure" "-Srepro" "-A:clojure-cli.repl/client" "-Spath" :dir (str dir))]
-      (if (zero? exit)
-        (str/trim out)
-        (println "clojure-cli.repl: could not resolve deps.edn in" (str dir) "-" (str/trim err))))))
-
-(defn classpath-files [^java.io.File dir ^String cp]
-  (map #(.toFile (.resolve (.toPath dir) ^String %))
-       (.split cp java.io.File/pathSeparator)))
-
-(defn config-classpath [location lib]
-  (when-let [cp (cli-classpath location lib)]
-    (classpath-files (dc/data-dir location lib) cp)))
-
-(defn load-config
-  "Puts the config classpath on a DynamicClassLoader installed as the thread's
-   context loader. A new loader is required because the app loader cannot be
-   extended. Returns the config map."
-  [lib]
-  (let [entries (distinct (mapcat #(config-classpath % lib) [:project :user]))]
-    (when (seq entries)
-      (let [thread (Thread/currentThread)
-            loader (clojure.lang.DynamicClassLoader. (.getContextClassLoader thread))]
-        (doseq [^java.io.File f entries]
-          (.addURL loader (.toURL (.toURI f))))
-        (.setContextClassLoader thread loader))))
-  (dc/config lib))
-
 (defn history-file
   "REPL history file, location is user configurable [:project|:user] under
    :history key, defaults to :user. Creates the parent dir if necessary."
@@ -386,13 +348,6 @@
         (exit-alt-screen term)
         (.callWidget rdr "redisplay")))))
 
-(defn apply-keybindings
-  [config reader]
-  (when-let [keybindings (:keybindings config)]
-    (if-let [f (requiring-resolve keybindings)]
-      (f reader)
-      (throw (ex-info (str "clojure-cli.repl: :keybindings var not found: " keybindings) {:keybindings keybindings})))))
-
 (defn auto-require
   "Requires libspecs in ns-name on the server.
    Prints the error if a libspec fails to load."
@@ -402,8 +357,8 @@
       (println "clojure-cli.repl: :auto-require failed:" error))))
 
 (defn -main [& args]
-  (let [config (load-config 'org.clojure/clojure-cli.repl)
-        prompt-fn (resolve-prompt config)
+  (let [config (host/load-config 'org.clojure/clojure-cli.repl)
+        prompt-fn (or (host/resolve-prompt config) default-prompt)
         port (Integer/parseInt (str/trim (or (first args) (slurp ".nrepl-port"))))
         {:keys [session]} (nrepl/connect port)
         libspecs (:auto-require config)
@@ -417,7 +372,7 @@
     (when-let [keyseq (:inspect config)]
       (api/bind-key rdr (api/key-sequence keyseq) (inspect rdr)))
     (paredit/install config rdr)
-    (apply-keybindings config rdr)
+    (host/apply-keybindings config rdr)
     ;; ctrl-c during an eval outside of .readLine needs to interrupt the server
     (.handle (.getTerminal rdr) Terminal$Signal/INT
              (reify Terminal$SignalHandler

doc/operations.md

@@ -33,6 +33,31 @@ Reply:
 {:doc "clojure.core/map\n..." :status ["done"]}
 ```
 
+## auto-require
+
+Require libspecs in a namespace. The client sends it on startup and on each namespace change.
+
+Request:
+
+| Key | Value |
+|-----|-------|
+| `:op` | `"auto-require"` |
+| `:libspecs` | the libspecs to require, as an EDN string |
+| `:ns` | the namespace to require them in |
+
+Reply:
+
+| Key | Value |
+|-----|-------|
+| `:error` | the failure message, present only when a libspec fails to load |
+
+```clojure
+;; request
+{:op "auto-require" :libspecs "[[clojure.string :as s]]" :ns "user"}
+;; reply
+{:status ["done"]}
+```
+
 ## inspect
 
 The server is responsible for holding and modifying the state of the inspector.