CMakeLists.txt

cmake_minimum_required(VERSION 3.21)

# This template attempts to be "fetch_content"-able
# so that it works well with tools like CPM or other
# manual dependency management

# Only set the cxx_standard if it is not set by someone else
if (NOT DEFINED CMAKE_CXX_STANDARD)
  set(CMAKE_CXX_STANDARD 20)
endif()

# strongly encouraged to enable this globally to avoid conflicts between
# -Wpedantic being enabled and -std=c++20 and -std=gnu++20 for example
# when compiling with PCH enabled
set(CMAKE_CXX_EXTENSIONS OFF)

# Set the project name and language
project(
  json2cpp
  VERSION 0.0.1
  DESCRIPTION ""
  HOMEPAGE_URL "%%myurl%%"
  LANGUAGES CXX C)

include(cmake/PreventInSourceBuilds.cmake)
include(ProjectOptions.cmake)


json2cpp_setup_options()

json2cpp_global_options()

if(NOT DEFINED CONAN_CXX_FLAGS)
  include(Dependencies.cmake)
  json2cpp_setup_dependencies()
endif()

json2cpp_local_options()

# don't know if this should be set globally from here or not...
set(CMAKE_CXX_VISIBILITY_PRESET hidden)

set(GIT_SHA
    "Unknown"
    CACHE STRING "SHA this build was generated from")
string(
  SUBSTRING "${GIT_SHA}"
            0
            8
            GIT_SHORT_SHA)

target_compile_features(json2cpp_options INTERFACE cxx_std_${CMAKE_CXX_STANDARD})

if(DEFINED CONAN_CXX_FLAGS)
  find_package(ValiJSON CONFIG)
endif()

add_library(json2cpp_headers INTERFACE)
target_include_directories(json2cpp_headers INTERFACE
  $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:include>)
target_link_libraries(json2cpp_headers INTERFACE ValiJSON::valijson)
install(DIRECTORY "${CMAKE_SOURCE_DIR}/include/json2cpp" TYPE INCLUDE)
add_library(json2cpp::json2cpp_headers ALIAS json2cpp_headers)
install(TARGETS json2cpp_headers EXPORT json2cppTargets)
export(EXPORT json2cppTargets NAMESPACE json2cpp::)
install(
  EXPORT json2cppTargets
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/json2cpp
  NAMESPACE json2cpp::
)

add_library(json2cpp::json2cpp_options ALIAS json2cpp_options)
add_library(json2cpp::json2cpp_warnings ALIAS json2cpp_warnings)

#add_library(json2cpp::json2cpp_options INTERFACE IMPORTED)
#add_library(json2cpp::json2cpp_warnings INTERFACE IMPORTED)

# configure files based on CMake configuration options

# Adding the src:
add_subdirectory(src)

# Don't even look at tests if we're not top level
if(NOT PROJECT_IS_TOP_LEVEL)
  return()
endif()

# Adding the tests:
include(CTest)

if(BUILD_TESTING)
  add_subdirectory(test)
endif()


if(json2cpp_BUILD_FUZZ_TESTS)
  message(AUTHOR_WARNING "Building Fuzz Tests, using fuzzing sanitizer https://www.llvm.org/docs/LibFuzzer.html")
  add_subdirectory(fuzz_test)
endif()

# If MSVC is being used, and ASAN is enabled, we need to set the debugger environment
# so that it behaves well with MSVC's debugger, and we can run the target from visual studio
if(MSVC)
  get_all_installable_targets(all_targets)
  message("all_targets=${all_targets}")
  set_target_properties(${all_targets} PROPERTIES VS_DEBUGGER_ENVIRONMENT "PATH=$(VC_ExecutablePath_x64);%PATH%")
endif()

# set the startup project for the "play" button in MSVC
set_property(DIRECTORY PROPERTY VS_STARTUP_PROJECT json2cpp)

if(CMAKE_SKIP_INSTALL_RULES)
  return()
endif()

if(DEFINED CONAN_CXX_FLAGS)
  return()
endif()

include(cmake/PackageProject.cmake)

# Add other targets that you want installed here, by default we just package the one executable
# we know we want to ship
json2cpp_package_project(
  TARGETS
  json2cpp
  json2cpp_options
  json2cpp_warnings
  # FIXME: this does not work! CK
  # PRIVATE_DEPENDENCIES_CONFIGURED project_options project_warnings
)

# Experience shows that explicit package naming can help make it easier to sort
# out potential ABI related issues before they start, while helping you
# track a build to a specific GIT SHA
set(CPACK_PACKAGE_FILE_NAME
    "${CMAKE_PROJECT_NAME}-${CMAKE_PROJECT_VERSION}-${GIT_SHORT_SHA}-${CMAKE_SYSTEM_NAME}-${CMAKE_BUILD_TYPE}-${CMAKE_CXX_COMPILER_ID}-${CMAKE_CXX_COMPILER_VERSION}"
)

include(CPack)