kotlin-sdk/build.gradle.kts at main · modelcontextprotocol/kotlin-sdk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
import dev.detekt.gradle.extensions.FailOnSeverity

plugins {
    id("mcp.dokka")
    alias(libs.plugins.detekt)
    alias(libs.plugins.ktlint)
    alias(libs.plugins.kover)
}

dependencies {
    dokka(project(":kotlin-sdk-core"))
    dokka(project(":kotlin-sdk-client"))
    dokka(project(":kotlin-sdk-server"))
    dokka(project(":kotlin-sdk-testing"))

    kover(project(":kotlin-sdk-core"))
    kover(project(":kotlin-sdk-client"))
    kover(project(":kotlin-sdk-server"))
    kover(project(":kotlin-sdk-testing"))
    kover(project(":integration-test"))
}

subprojects {
    apply(plugin = "org.jlleitschuh.gradle.ktlint")
    apply(plugin = "org.jetbrains.kotlinx.kover")

    if (name != "conformance-test" && name != "docs") {
        apply(plugin = "dev.detekt")

        detekt {
            config = files("$rootDir/config/detekt/detekt.yml")
            buildUponDefaultConfig = true
            failOnSeverity.set(FailOnSeverity.Error)
        }
    }
}

dokka {
    moduleName = "MCP Kotlin SDK"

    dokkaPublications.html {
        includes.from("docs/moduledoc.md")
    }
}

ktlint {
    filter {
        exclude("**/generated*/**")
    }
}

kover {
    reports {
        filters {
            includes.classes("io.modelcontextprotocol.kotlin.sdk.*")
            excludes {
                annotatedBy("kotlin.Deprecated")
                classes("io.modelcontextprotocol.kotlin.sdk.models.*") // temporary
                classes("io.modelcontextprotocol.kotlin.sdk.models.infrastructure.*") // generated
            }
        }
        total {
            log {
            }
            verify {
                rule {
                    minBound(73)
                }
            }
        }
    }
}