meta: Create a justfile for invoking common commands

The fuzzing commands are rather repetitive, so add an simpler way to run
them.

Author: tgross35

README.md

@@ -81,11 +81,21 @@ hardware floating-point behavior) is to employ *fuzzing*.
 The fuzzing infrastructure lives in `fuzz/` and requires `cargo-afl`, but also
 involves an automated build of the original C++ `llvm::APFloat` code with `clang`
 (to be able to instrument it via LLVM, in the same way `cargo-afl` does for the
-Rust code), and has been prototyped and tested on Linux (and is unlikely to work
-on other platforms, or even some Linux distros, though it mostly assumes UNIX).
+Rust code), and has been prototyped and tested on Linux. It is unlikely to work
+on other platforms, or even some Linux distros, though it mostly assumes UNIX.
 
-Example usage:
-<sub>(**TODO**: maybe move this to `fuzz/README.md` and/or expand on it)</sub>
+There is a justfile that makes this easy:
+
+```sh
+# Build and run fuzzing
+just fuzz
+# Do the same thing but use more cores
+just fuzz-parallel
+# Print crashes. Can be run while fuzzing is ongoing.
+just decode
+```
+
+Longer version:
 
 ```sh
 # Install `cargo-afl` (used below to build/run the fuzzing binary).

etc/fuzz-parallel.sh

@@ -9,8 +9,8 @@ set -euxo pipefail
 # Detect cores
 all_cores="$(nproc)"
 used_cores="$((all_cores - 2))"
-in_dir="fuzz/runs/fuzz-in"
-sync_dir="fuzz/runs/fuzz-out"
+in_dir="${FUZZ_IN:-fuzz/runs/in}"
+sync_dir="${FUZZ_OUT:-fuzz/runs/out}"
 tmux_window=afl
 
 if [[ "$used_cores" -lt 2 ]]; then

fuzz/src/main.rs

@@ -576,7 +576,8 @@ fn run_decode_subcmd(files: &[PathBuf], cli_args: &Args) {
         match decode_eval_check(&buf, cli_args, true) {
             Ok(()) => (),
             Err(Error::Decode(e)) => println!("error decoding file: {e}"),
-            Err(Error::Check(e)) => println!("check error: {e:?}"),
+            // No need to print anything extra, we already get the mismatch messages.
+            Err(Error::Check(_e)) => (),
         }
     }
 }

justfile

@@ -0,0 +1,46 @@
+# Allow overriding the fuzz directories
+fuzz_in := env("FUZZ_IN", "fuzz/runs/in")
+fuzz_out := env("FUZZ_OUT", "fuzz/runs/out")
+
+alias f := fuzz
+alias fp := fuzz-parallel
+alias fa := fuzz-attach
+alias fq := fuzz-parallel-quit
+alias d := decode
+alias t := test
+
+_default:
+    {{ just_executable() }} --list
+
+# Run non-fuzzing tests
+test:
+    cargo test --workspace
+
+# Create directories and build the executable, but don't start fuzzing.
+_fuzz-setup:
+    mkdir -p "{{ fuzz_in }}"
+    echo > "{{ fuzz_in }}/empty"
+    cargo afl build -p rustc_apfloat-fuzz --release
+
+# Build the instrumented executable and fuzz it. See also: `fuzz-parallel`.
+fuzz: _fuzz-setup
+    cargo afl fuzz -i "{{ fuzz_in }}" -o "{{ fuzz_out }}" target/release/rustc_apfloat-fuzz
+
+# Start fuzzing in parallel. Note this must be stopped with fuzz-parallel-quit (see fuzz-parallel.sh).
+fuzz-parallel *args: _fuzz-setup
+    etc/fuzz-parallel.sh {{ args }}
+
+# Attach to a running parallel fuzz session
+fuzz-attach:
+    tmux attach -t afl01
+
+# Stop parallel fuzzing
+fuzz-parallel-quit:
+    tmux list-sessions | cut -d':' -f1 | grep afl | xargs -iSESS tmux kill-session -t SESS
+
+all-crashes := '"' + fuzz_out + '"/*/crashes/*'
+
+# Print the result of crashes in the fuzz output directory
+decode *paths=all-crashes:
+    ls {{ all-crashes }}
+    cargo run -p rustc_apfloat-fuzz -- decode {{ paths }}