testcontainers-java/modules/neo4j/build.gradle at b85a7d820425fc5f6b9c6b1abfb9223c87b4334e · testcontainers/testcontainers-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
description = "Testcontainers :: Neo4j"

def generatedResourcesDir = new File(project.buildDir, "generated-resources")
def customNeo4jPluginDestinationDir = new File(generatedResourcesDir, "custom-plugins")

sourceSets {
    customNeo4jPlugin {
        java {
            srcDir 'src/custom-neo4j-plugin'
        }
    }
    test {
        resources {
            srcDir generatedResourcesDir
        }
    }
}

task customNeo4jPluginJar(type: Jar) {
    from sourceSets.customNeo4jPlugin.output
    archiveFileName = "hello-world.jar"
    destinationDirectory = customNeo4jPluginDestinationDir

    inputs.files(sourceSets.customNeo4jPlugin.java.srcDirs)
    outputs.cacheIf { true }
    outputs.dir(customNeo4jPluginDestinationDir)
}

processTestResources.dependsOn customNeo4jPluginJar

dependencies {
    customNeo4jPluginCompileOnly "org.neo4j:neo4j:3.5.35"

    api project(":testcontainers")

    testImplementation 'org.neo4j.driver:neo4j-java-driver:4.4.22'
}